local PipelineBuild(os='linux', arch='amd64', version='gce') = {
  local tag = os + '-' + arch,
  local version_tag = version + '-' + os + '-' + arch,
  local file_suffix = std.strReplace(version_tag, '-', '.'),
  kind: "pipeline",
  name: version_tag,
  platform: {
    os: os,
    arch: arch,
  },
  steps: [
    {
      name: 'dryrun',
      image: 'plugins/docker:' + tag,
      pull: 'always',
      settings: {
        dry_run: true,
        tags: version_tag,
        dockerfile: 'docker/Dockerfile.' + file_suffix,
        repo: ' xoxys/molecule',
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
      },
    },
    {
      name: 'publish',
      image: 'plugins/docker:' + tag,
      pull: 'always',
      settings: {
        auto_tag: true,
        auto_tag_suffix: version_tag,
        dockerfile: 'docker/Dockerfile.' + file_suffix,
        repo: ' xoxys/molecule',
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
      },
      when: {
        branch: [ "master" ],
      },
    },
  ],
};

local PipelineNotifications(depends_on=[]) = {
  kind: "pipeline",
  name: "notifications",
  platform: {
    os: "linux",
    arch: "amd64",
  },
  steps: [
    {
      image: "plugins/manifest",
      name: "manifest",
      pull: "always",
      settings: {
        ignore_missing: true,
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
        spec: "docker/manifest.tmpl",
      },
      when: {
        branch: [ "master" ],
      },
    },
    {
      name: "microbadger",
      image: "plugins/webhook",
      pull: "always",
      settings: {
        urls: { from_secret: "microbadger_url" },
      },
    },
    {
      image: "plugins/matrix",
      name: "matrix",
      pull: 'always',
      settings: {
        homeserver: "https://matrix.rknet.org",
        roomid: "MtidqQXWWAtQcByBhH:rknet.org",
        template: "Status: **{{ build.status }}**<br/> Build: [{{ repo.Owner }}/{{ repo.Name }}]({{ build.link }}) ({{ build.branch }}) by {{ build.author }}<br/> Message: {{ build.message }}",
        username: { from_secret: "matrix_username" },
        password: { from_secret: "matrix_password" },
      },
      when: {
        status: [ "success", "failure" ],
      },
    },
  ],
  trigger: {
    status: [ "success", "failure" ],
  },
  depends_on: depends_on,
};

[
  PipelineBuild(os='linux', arch='amd64', version='gce'),
  PipelineBuild(os='linux', arch='amd64', version='ec2'),
  PipelineNotifications(depends_on=[
    "gce-linux-amd64",
    "ec2-linux-amd64"
  ])
]