molecule/.drone.jsonnet

local PipelineBuild(os='linux', arch='amd64', version='gce') = {
  local tag = os + '-' + arch,
  local version_tag = version + '-' + os + '-' + arch,
  local file_suffix = std.strReplace(version_tag, '-', '.'),
  kind: "pipeline",
  name: version_tag,
  platform: {
    os: os,
    arch: arch,
  },
  steps: [
    {
      name: 'dryrun',
      image: 'plugins/docker:' + tag,
      pull: 'always',
      settings: {
        dry_run: true,
        tags: version_tag,
        dockerfile: 'docker/Dockerfile.' + file_suffix,
        repo: ' xoxys/molecule',
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
      },
    },
    {
      name: 'publish',
      image: 'plugins/docker:' + tag,
      pull: 'always',
      settings: {
        auto_tag: true,
        auto_tag_suffix: version_tag,
        dockerfile: 'docker/Dockerfile.' + file_suffix,
        repo: ' xoxys/molecule',
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
      },
      when: {
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
      },
    },
  ],
};

local PipelineNotifications(depends_on=[]) = {
  kind: "pipeline",
  name: "notifications",
  platform: {
    os: "linux",
    arch: "amd64",
  },
  steps: [
    {
      image: "plugins/manifest",
      name: "manifest",
      pull: "always",
      settings: {
        ignore_missing: true,
        username: { from_secret: "docker_username" },
        password: { from_secret: "docker_password" },
        spec: "docker/manifest.tmpl",
      },
      when: {
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
        status: [ "success" ],
      },
    },
    {
      name: "readme",
      image: "sheogorath/readme-to-dockerhub",
      pull: "always",
      environment: {
        DOCKERHUB_USERNAME: { from_secret: "docker_username" },
        DOCKERHUB_PASSWORD: { from_secret: "docker_password" },
        DOCKERHUB_REPO_PREFIX: "xoxys",
        DOCKERHUB_REPO_NAME: "molecule",
        README_PATH: "README.md",
        SHORT_DESCRIPTION: "Molecule - Automated Ansible roles testing"
      },
      when: {
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
        status: [ "success" ],
      },
    },
    {
      name: "microbadger",
      image: "plugins/webhook",
      pull: "always",
      settings: {
        urls: { from_secret: "microbadger_url" },
      },
      when: {
        status: [ "success" ],
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
      },
    },
    {
      name: "matrix",
      image: "plugins/matrix",
      pull: 'always',
      settings: {
        homeserver: "https://matrix.rknet.org",
        roomid: "MtidqQXWWAtQcByBhH:rknet.org",
        template: "Status: **{{ build.status }}**<br/> Build: [{{ repo.Owner }}/{{ repo.Name }}]({{ build.link }}) ({{ build.branch }}) by {{ build.author }}<br/> Message: {{ build.message }}",
        username: { from_secret: "matrix_username" },
        password: { from_secret: "matrix_password" },
      },
      when: {
        status: [ "success", "failure" ],
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
      },
    },
  ],
  trigger: {
    status: [ "success", "failure" ],
  },
  depends_on: depends_on,
};

[
  PipelineBuild(os='linux', arch='amd64', version='gce'),
  PipelineBuild(os='linux', arch='amd64', version='ec2'),
  PipelineBuild(os='linux', arch='amd64', version='do'),
  PipelineBuild(os='linux', arch='amd64', version='hcloud'),
  PipelineNotifications(depends_on=[
    "gce-linux-amd64",
    "ec2-linux-amd64",
    "do-linux-amd64",
    "hcloud-linux-amd64"
  ])
]