vaultwarden-ldap/.drone.jsonnet

local PipelineBuild(arch='amd64') = {
  local tag = 'linux-' + arch,
  kind: 'pipeline',
  name: 'build-container-' + arch,
  platform: {
    os: 'linux',
    arch: arch,
  },
  steps: [
    {
      name: 'binary',
      image: 'clux/muslrust:nightly-2019-12-19',
      environment: {
        'DB': 'postgresql',
        'DEBIAN_FRONTEND': 'noninteractive',
        'LANG': 'C.UTF-8',
        'TZ': 'UTC',
      },
      commands: [
        '[ -z "${DRONE_TAG}" ] && LDAP_VERSION=master || LDAP_VERSION=v${DRONE_TAG%-*}',
        'mkdir -p source/',
        'rustup set profile minimal',
        'curl -sSL https://github.com/ViViDboarder/bitwarden_rs_ldap/archive/$LDAP_VERSION.tar.gz | tar xz -C source/ --strip-components=1',
        "grep -rlI 'Box<Error>' source/src/ | xargs sed -i 's/Box<Error>/Box<dyn Error>/g'",
        'cd source/ && cargo build -j 8 --release',
      ],
    },
    {
      name: 'dryrun',
      image: 'plugins/docker:' + tag,
      settings: {
        dry_run: true,
        dockerfile: './Dockerfile.' + arch,
        repo: 'xoxys/bitwardenrs_ldap',
        username: { from_secret: 'docker_username' },
        password: { from_secret: 'docker_password' },
      },
    },
    {
      name: 'publish',
      image: 'plugins/docker:' + tag,
      settings: {
        auto_tag: true,
        auto_tag_suffix: arch,
        dockerfile: './Dockerfile.' + arch,
        repo: 'xoxys/bitwardenrs_ldap',
        username: { from_secret: 'docker_username' },
        password: { from_secret: 'docker_password' },
      },
      when: {
        ref: [
          'refs/heads/master',
          'refs/tags/**',
        ],
      },
    },
    {
      name: 'publish-gitea',
      image: 'plugins/gitea-release',
      settings: {
        api_key: { from_secret: 'gitea_token' },
        base_url: 'https://gitea.rknet.org',
        overwrite: true,
        title: '${DRONE_TAG}',
        note: 'CHANGELOG.md',
      },
      when: {
        ref: ['refs/tags/**'],
      },
    },
  ],
};

local PipelineNotifications(depends_on=[]) = {
  kind: 'pipeline',
  name: 'notifications',
  platform: {
    os: 'linux',
    arch: 'amd64',
  },
  steps: [
    {
      image: 'plugins/manifest',
      name: 'manifest',
      settings: {
        ignore_missing: true,
        tags: ['${DRONE_TAG}', '${DRONE_TAG%-*}', '${DRONE_TAG%.*}', '${DRONE_TAG%%.*}'],
        username: { from_secret: 'docker_username' },
        password: { from_secret: 'docker_password' },
        spec: './manifest.tmpl',
      },
      when: {
        status: ['success'],
      },
    },
    {
      name: 'readme',
      image: 'sheogorath/readme-to-dockerhub',
      environment: {
        DOCKERHUB_USERNAME: { from_secret: 'docker_username' },
        DOCKERHUB_PASSWORD: { from_secret: 'docker_password' },
        DOCKERHUB_REPO_PREFIX: 'xoxys',
        DOCKERHUB_REPO_NAME: 'bitwardenrs_ldap',
        README_PATH: 'README.md',
        SHORT_DESCRIPTION: 'Rootless Bitwarden_RS - Self-hosted password manager',
      },
    },
    {
      name: 'microbadger',
      image: 'plugins/webhook',
      settings: {
        urls: { from_secret: 'microbadger_url' },
      },
    },
    {
      image: 'plugins/matrix',
      name: 'matrix',
      settings: {
        homeserver: 'https://matrix.rknet.org',
        roomid: 'MtidqQXWWAtQcByBhH:rknet.org',
        template: 'Status: **{{ build.status }}**<br/> Build: [{{ repo.Owner }}/{{ repo.Name }}]({{ build.link }}) ({{ build.branch }}) by {{ build.author }}<br/> Message: {{ build.message }}',
        username: { from_secret: 'matrix_username' },
        password: { from_secret: 'matrix_password' },
      },
      when: {
        status: ['success', 'failure'],
      },
    },
  ],
  trigger: {
    ref: [
      'refs/heads/master',
      'refs/tags/**',
    ],
    status: ['success', 'failure'],
  },
  depends_on: depends_on,
};

[
  PipelineBuild(arch='amd64'),
  PipelineNotifications(depends_on=[
    'build-container-amd64',
  ]),
]